mirror of
https://github.com/spring-projects/spring-boot.git
synced 2024-06-30 00:36:49 +08:00
94 lines
4.0 KiB
Groovy
94 lines
4.0 KiB
Groovy
pluginManagement {
|
|
repositories {
|
|
mavenCentral()
|
|
gradlePluginPortal()
|
|
if (version.endsWith('-SNAPSHOT')) {
|
|
maven { url "https://repo.spring.io/snapshot" }
|
|
}
|
|
}
|
|
resolutionStrategy {
|
|
eachPlugin {
|
|
if (requested.id.id == "org.jetbrains.kotlin.jvm") {
|
|
useVersion "${kotlinVersion}"
|
|
}
|
|
if (requested.id.id == "org.jetbrains.kotlin.plugin.spring") {
|
|
useVersion "${kotlinVersion}"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
plugins {
|
|
id "com.gradle.develocity" version "3.17.2"
|
|
id "io.spring.ge.conventions" version "0.0.17"
|
|
}
|
|
|
|
rootProject.name="spring-boot-build"
|
|
|
|
enableFeaturePreview("STABLE_CONFIGURATION_CACHE")
|
|
|
|
settings.gradle.projectsLoaded {
|
|
develocity {
|
|
buildScan {
|
|
def toolchainVersion = settings.gradle.rootProject.findProperty('toolchainVersion')
|
|
if (toolchainVersion != null) {
|
|
value('Toolchain version', toolchainVersion)
|
|
tag("JDK-$toolchainVersion")
|
|
}
|
|
def buildDir = settings.gradle.rootProject.getBuildDir()
|
|
buildDir.mkdirs()
|
|
new File(buildDir, "build-scan-uri.txt").text = "build scan not generated"
|
|
buildScanPublished { scan ->
|
|
buildDir.mkdirs()
|
|
new File(buildDir, "build-scan-uri.txt").text = "<${scan.buildScanUri}|build scan>\n"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
include "spring-boot-project:spring-boot-dependencies"
|
|
include "spring-boot-project:spring-boot-parent"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-antlib"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-autoconfigure-processor"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-buildpack-platform"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-cli"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-configuration-metadata"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-configuration-metadata-changelog-generator"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-configuration-processor"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-gradle-plugin"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-gradle-test-support"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-jarmode-tools"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-loader"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-loader-classic"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-loader-tools"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-maven-plugin"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-properties-migrator"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-test-support"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-test-support-docker"
|
|
include "spring-boot-project:spring-boot"
|
|
include "spring-boot-project:spring-boot-autoconfigure"
|
|
include "spring-boot-project:spring-boot-actuator"
|
|
include "spring-boot-project:spring-boot-actuator-autoconfigure"
|
|
include "spring-boot-project:spring-boot-docker-compose"
|
|
include "spring-boot-project:spring-boot-devtools"
|
|
include "spring-boot-project:spring-boot-docs"
|
|
include "spring-boot-project:spring-boot-test"
|
|
include "spring-boot-project:spring-boot-testcontainers"
|
|
include "spring-boot-project:spring-boot-test-autoconfigure"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-configuration-processor-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-launch-script-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-loader-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-loader-classic-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-server-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-sni-tests"
|
|
include "spring-boot-system-tests:spring-boot-deployment-tests"
|
|
include "spring-boot-system-tests:spring-boot-image-tests"
|
|
|
|
file("${rootDir}/spring-boot-project/spring-boot-starters").eachDirMatch(~/spring-boot-starter.*/) {
|
|
include "spring-boot-project:spring-boot-starters:${it.name}"
|
|
}
|
|
|
|
file("${rootDir}/spring-boot-tests/spring-boot-smoke-tests").eachDirMatch(~/spring-boot-smoke-test.*/) {
|
|
include "spring-boot-tests:spring-boot-smoke-tests:${it.name}"
|
|
}
|