mirror of
https://github.com/spring-projects/spring-boot.git
synced 2024-07-05 00:56:58 +08:00
18c7c0af22
A new system test plugin is being made available for running test suites that should be run less frequently than with every commit, such as tests that verify Spring Boot compatibility with external projects. CI pipeline configuration for running system tests is also provided. The first system tests verify the behavior of the Spring Boot image building plugins when building images using Paketo buildpacks. Closes gh-25824
87 lines
3.4 KiB
Groovy
87 lines
3.4 KiB
Groovy
pluginManagement {
|
|
repositories {
|
|
mavenCentral()
|
|
gradlePluginPortal()
|
|
maven {
|
|
url 'https://repo.spring.io/plugins-release'
|
|
}
|
|
if (version.endsWith('-SNAPSHOT')) {
|
|
maven { url "https://repo.spring.io/snapshot" }
|
|
}
|
|
}
|
|
resolutionStrategy {
|
|
eachPlugin {
|
|
if (requested.id.id == "org.jetbrains.kotlin.jvm") {
|
|
useVersion "${kotlinVersion}"
|
|
}
|
|
if (requested.id.id == "org.jetbrains.kotlin.plugin.spring") {
|
|
useVersion "${kotlinVersion}"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
plugins {
|
|
id "com.gradle.enterprise" version "3.6.1"
|
|
id "io.spring.ge.conventions" version "0.0.7"
|
|
}
|
|
|
|
rootProject.name="spring-boot-build"
|
|
|
|
settings.gradle.projectsLoaded {
|
|
gradleEnterprise {
|
|
buildScan {
|
|
def toolchainVersion = settings.gradle.rootProject.findProperty('toolchainVersion')
|
|
if (toolchainVersion != null) {
|
|
value('Toolchain version', toolchainVersion)
|
|
tag("JDK-$toolchainVersion")
|
|
}
|
|
|
|
settings.gradle.rootProject.getBuildDir().mkdirs()
|
|
new File(settings.gradle.rootProject.getBuildDir(), "build-scan-uri.txt").text = "build scan not generated"
|
|
|
|
buildScanPublished { scan ->
|
|
new File(settings.gradle.rootProject.getBuildDir(), "build-scan-uri.txt").text = "<${scan.buildScanUri}|build scan>\n"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
include "spring-boot-project:spring-boot-dependencies"
|
|
include "spring-boot-project:spring-boot-parent"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-antlib"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-autoconfigure-processor"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-buildpack-platform"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-configuration-metadata"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-configuration-processor"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-gradle-plugin"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-jarmode-layertools"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-loader"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-loader-tools"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-maven-plugin"
|
|
include "spring-boot-project:spring-boot-tools:spring-boot-test-support"
|
|
include "spring-boot-project:spring-boot"
|
|
include "spring-boot-project:spring-boot-autoconfigure"
|
|
include "spring-boot-project:spring-boot-actuator"
|
|
include "spring-boot-project:spring-boot-actuator-autoconfigure"
|
|
include "spring-boot-project:spring-boot-cli"
|
|
include "spring-boot-project:spring-boot-devtools"
|
|
include "spring-boot-project:spring-boot-docs"
|
|
include "spring-boot-project:spring-boot-properties-migrator"
|
|
include "spring-boot-project:spring-boot-test"
|
|
include "spring-boot-project:spring-boot-test-autoconfigure"
|
|
include "spring-boot-tests:spring-boot-deployment-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-configuration-processor-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-launch-script-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-loader-tests"
|
|
include "spring-boot-tests:spring-boot-integration-tests:spring-boot-server-tests"
|
|
include "spring-boot-system-tests:spring-boot-image-tests"
|
|
|
|
file("${rootDir}/spring-boot-project/spring-boot-starters").eachDirMatch(~/spring-boot-starter.*/) {
|
|
include "spring-boot-project:spring-boot-starters:${it.name}"
|
|
}
|
|
|
|
file("${rootDir}/spring-boot-tests/spring-boot-smoke-tests").eachDirMatch(~/spring-boot-smoke-test.*/) {
|
|
include "spring-boot-tests:spring-boot-smoke-tests:${it.name}"
|
|
}
|